a2382f7f15
abuses have been observed in the wild, so make sure these variables are not available. Change-Id: I502c3f5db7d341cf6a8bd2ec09e87f129da2fca6 Reviewed-by: Mark Brand <mabrand@mabrand.nl>
36 lines
1.5 KiB
Plaintext
36 lines
1.5 KiB
Plaintext
QMAKE_QT_CONFIG = $$[QT_HOST_DATA/get]/mkspecs/qconfig.pri
|
|
!exists($$QMAKE_QT_CONFIG)|!include($$QMAKE_QT_CONFIG, "", true) {
|
|
debug(1, "Cannot load qconfig.pri!")
|
|
} else {
|
|
debug(1, "Loaded .qconfig.pri from ($$QMAKE_QT_CONFIG)")
|
|
QMAKE_MODULE_PATH = $$split($$list($$(QMAKEMODULES)), $$DIRLIST_SEPARATOR)
|
|
QMAKE_MODULE_PATH += $$QMAKEMODULES
|
|
QMAKE_MODULE_PATH += $$split($$list($$[QMAKEMODULES]), $$DIRLIST_SEPARATOR)
|
|
QMAKE_MODULE_PATH += $$replace($$list($$split($$list($$[QMAKE_MKSPECS]), $$DIRLIST_SEPARATOR)), \
|
|
\$, /modules)
|
|
QMAKE_MODULE_PATH = $$unique(QMAKE_MODULE_PATH)
|
|
QMAKE_MODULE_PATH = $$reverse(QMAKE_MODULE_PATH)
|
|
for(dir, QMAKE_MODULE_PATH) {
|
|
debug(1, "Loading modules from $${dir}")
|
|
for(mod, $$list($$files($$dir/qt_*.pri))) {
|
|
# For installed Qt these paths will be common for all modules
|
|
# For development these will vary per module, and syncqt will override the value in the
|
|
# qt_<module>.pri forwarding file
|
|
QT_MODULE_INCLUDE_BASE = $$[QT_INSTALL_HEADERS]
|
|
QT_MODULE_LIB_BASE = $$[QT_INSTALL_LIBS]
|
|
QT_MODULE_PLUGIN_BASE = $$[QT_INSTALL_PLUGINS]
|
|
QT_MODULE_BIN_BASE = $$[QT_INSTALL_BINS]
|
|
QT_MODULE_IMPORT_BASE = $$[QT_INSTALL_IMPORTS]
|
|
include($$mod)
|
|
}
|
|
}
|
|
unset(QT_MODULE_INCLUDE_BASE)
|
|
unset(QT_MODULE_LIB_BASE)
|
|
unset(QT_MODULE_PLUGIN_BASE)
|
|
unset(QT_MODULE_BIN_BASE)
|
|
unset(QT_MODULE_IMPORT_BASE)
|
|
}
|
|
|
|
load(qt_functions)
|
|
|