c013104b04
This is a temporary measure while the Qt CI system is updated to have the correct D-Bus configuration. Once it is fixed, this commit should be reverted, so that we don't run into the situation in which the tests aren't getting run on some configurations and we never know about it. Change-Id: I7192d4d95a60dcb63acfa6cc90bfdc58592b0664 Reviewed-by: Alex Blasche <alexander.blasche@theqtcompany.com>
42 lines
1.1 KiB
Prolog
42 lines
1.1 KiB
Prolog
TEMPLATE = subdirs
|
|
|
|
SUBDIRS += \
|
|
corelib \
|
|
dbus \
|
|
gui \
|
|
network \
|
|
opengl \
|
|
sql \
|
|
testlib \
|
|
tools \
|
|
xml \
|
|
concurrent \
|
|
other \
|
|
widgets \
|
|
printsupport \
|
|
cmake \
|
|
installed_cmake
|
|
|
|
installed_cmake.depends = cmake
|
|
|
|
ios: SUBDIRS = corelib gui
|
|
|
|
wince*: SUBDIRS -= printsupport
|
|
cross_compile: SUBDIRS -= tools
|
|
!qtHaveModule(opengl): SUBDIRS -= opengl
|
|
!qtHaveModule(gui): SUBDIRS -= gui cmake
|
|
!qtHaveModule(widgets): SUBDIRS -= widgets
|
|
!qtHaveModule(printsupport): SUBDIRS -= printsupport
|
|
!qtHaveModule(concurrent): SUBDIRS -= concurrent
|
|
!qtHaveModule(network): SUBDIRS -= network
|
|
|
|
# Disable the QtDBus tests if we can't connect to the session bus
|
|
qtHaveModule(dbus) {
|
|
!system("dbus-send --type=signal / local.AutotestCheck.Hello"): {
|
|
warning("QtDBus is enabled but session bus is not available. Please check the installation.")
|
|
SUBDIRS -= dbus
|
|
}
|
|
} else {
|
|
SUBDIRS -= dbus
|
|
}
|