d6d3a32a68
separate_debug_info was previously stored in .qmake.cache, and therefore only affected qtbase. Store it as a QT_CONFIG setting instead, and add it to CONFIG for all Qt plugins and modules. Change-Id: I940c8cb30f1c42c85f4d0342e6a482f20677ff04 Reviewed-on: http://codereview.qt.nokia.com/2975 Reviewed-by: Qt Sanity Bot <qt_sanity_bot@ovi.com> Reviewed-by: Oswald Buddenhagen <oswald.buddenhagen@nokia.com> Reviewed-by: Marius Storm-Olsen <marius.storm-olsen@nokia.com>
44 lines
1.4 KiB
Plaintext
44 lines
1.4 KiB
Plaintext
TEMPLATE = lib
|
|
isEmpty(QT_MAJOR_VERSION) {
|
|
VERSION=5.0.0
|
|
} else {
|
|
VERSION=$${QT_MAJOR_VERSION}.$${QT_MINOR_VERSION}.$${QT_PATCH_VERSION}
|
|
}
|
|
CONFIG += qt plugin
|
|
|
|
win32|mac:!wince*:!win32-msvc:!macx-xcode:CONFIG += debug_and_release
|
|
TARGET = $$qtLibraryTarget($$TARGET)
|
|
contains(QT_CONFIG, reduce_exports):CONFIG += hide_symbols
|
|
contains(QT_CONFIG, separate_debug_info):CONFIG += separate_debug_info
|
|
contains(QT_CONFIG, separate_debug_info_nocopy):CONFIG += separate_debug_info_nocopy
|
|
|
|
load(qt_targets)
|
|
|
|
wince*:LIBS += $$QMAKE_LIBS_GUI
|
|
|
|
symbian: {
|
|
TARGET.EPOCALLOWDLLDATA=1
|
|
TARGET.CAPABILITY = All -Tcb
|
|
TARGET = $${TARGET}$${QT_LIBINFIX}
|
|
load(armcc_warnings)
|
|
|
|
# Make partial upgrade SIS file for Qt plugin dll's
|
|
# Partial upgrade SIS file
|
|
vendorinfo = \
|
|
"; Localised Vendor name" \
|
|
"%{\"Nokia\"}" \
|
|
" " \
|
|
"; Unique Vendor name" \
|
|
":\"Nokia, Qt\"" \
|
|
" "
|
|
isEmpty(QT_LIBINFIX): PARTIAL_UPGRADE_UID = 0x2001E61C
|
|
else: PARTIAL_UPGRADE_UID = 0xE001E61C
|
|
|
|
pu_header = "; Partial upgrade package for testing $${TARGET} changes without reinstalling everything" \
|
|
"$${LITERAL_HASH}{\"$${TARGET}\"}, ($$PARTIAL_UPGRADE_UID), $${QT_MAJOR_VERSION},$${QT_MINOR_VERSION},$${QT_PATCH_VERSION}, TYPE=PU"
|
|
partial_upgrade.pkg_prerules = pu_header vendorinfo
|
|
partial_upgrade.files = $$QMAKE_LIBDIR_QT/$${TARGET}.dll
|
|
partial_upgrade.path = c:/sys/bin
|
|
DEPLOYMENT += partial_upgrade
|
|
}
|