14abec45f0
sk_app has existing support for Dawn on top of Vulkan, and this adds support to build //example:hello_world_dawn and get this to run on Linux. Dawn depends on Tint and abseil-cpp. Tint further depends on spirv_tools and spirv_headers (for writing to the SPIR-V format). Dawn and Tint only have GN and CMake support, so we need to make our Bazel rules for them (see //third_party/BUILD.bazel). abseil-cpp and the SPIR-V libraries have Bazel support, so we can just include them (see //WORKSPACE.bazel). It is important that @spirv_headers be called that exactly because @spirv_tools depends on it by that name. The hand-crafted cc_library rules for Dawn and Tint were produced by reading the appropriate GN files and using the parts necessary for a supporting Vulkan+Linux. If we use Dawn for other backends (e.g. WebGPU), we will need to expand the Bazel rules. One day, we might contribute the Bazel rules to Dawn and Tint so they can support them and avoid breaking us if new files are added. Suggested Review Order - bazel/common_config_settings/BUILD.bazel to see introduction of new select-able option "has_gpu_backend" which cleans up some of our code that is enabled for any GPU backend. - src/*/BUILD.bazel to see has_gpu_backend rolled out. - WORKSPACE.bazel to see DEPS declared there (using the files in third_party/externals, which are brought in via tools/git-sync-deps). - third_party/BUILD.bazel which adds Dawn and Tint rules. It may be helpful to look in third_party/externals for the Dawn [1] and Tint [2] GN files. Especially interesting are the Python scripts [3] Dawn uses to generate some header and source files. - All other files. [1] https://dawn.googlesource.com/dawn/+/d9f22ce0346b222759d5510be3d1cd93caa5ab86/src/dawn/native/BUILD.gn#183 [2] https://dawn.googlesource.com/tint/+/453d5ae84ec30ab51ac592c13d472412ae8b5fc9/src/tint/BUILD.gn#174 [3] https://dawn.googlesource.com/dawn/+/d9f22ce0346b222759d5510be3d1cd93caa5ab86/generator/dawn_json_generator.py#774 Change-Id: Ied5b162045d8e841b9666457f0158457e2b078d4 Reviewed-on: https://skia-review.googlesource.com/c/skia/+/516996 Reviewed-by: Ben Wagner <bungeman@google.com> Reviewed-by: Greg Daniel <egdaniel@google.com> Commit-Queue: Kevin Lubick <kjlubick@google.com>
91 lines
2.4 KiB
Python
91 lines
2.4 KiB
Python
# https://github.com/bazelbuild/bazel-skylib
|
|
load("@bazel_skylib//lib:selects.bzl", "selects")
|
|
load("//bazel:macros.bzl", "select_multi")
|
|
load("@bazel_gazelle//:def.bzl", "gazelle")
|
|
|
|
package(default_visibility = ["//:__subpackages__"])
|
|
|
|
selects.config_setting_group(
|
|
name = "needs_jpeg",
|
|
match_any = [
|
|
"//bazel/common_config_settings:raw_decode_codec",
|
|
"//bazel/common_config_settings:jpeg_decode_codec",
|
|
"//bazel/common_config_settings:jpeg_encode_codec",
|
|
],
|
|
)
|
|
|
|
selects.config_setting_group(
|
|
name = "needs_png",
|
|
match_any = [
|
|
"//bazel/common_config_settings:png_decode_codec",
|
|
"//bazel/common_config_settings:png_encode_codec",
|
|
],
|
|
)
|
|
|
|
selects.config_setting_group(
|
|
name = "needs_webp",
|
|
match_any = [
|
|
"//bazel/common_config_settings:webp_decode_codec",
|
|
"//bazel/common_config_settings:webp_encode_codec",
|
|
],
|
|
)
|
|
|
|
selects.config_setting_group(
|
|
name = "any_freetype_fontmgr",
|
|
match_any = [
|
|
"//bazel/common_config_settings:custom_directory_fontmgr",
|
|
"//bazel/common_config_settings:custom_embedded_fontmgr",
|
|
"//bazel/common_config_settings:custom_empty_fontmgr",
|
|
],
|
|
)
|
|
|
|
CORE_DEPS = [
|
|
"//src/android:srcs",
|
|
"//src/codec:srcs",
|
|
"//src/core:srcs",
|
|
"//src/image:srcs",
|
|
"//src/images:srcs",
|
|
"//src/effects:srcs",
|
|
"//src/opts:srcs",
|
|
"//src/pathops:srcs",
|
|
"//src/ports:srcs",
|
|
"//src/sfnt:srcs",
|
|
"//src/shaders:srcs",
|
|
"//src/utils:srcs",
|
|
"//third_party:skcms",
|
|
] + select({
|
|
"//bazel/common_config_settings:has_gpu_backend": [
|
|
"//src/gpu:srcs",
|
|
"//src/sksl:srcs",
|
|
# TODO(kjlubick) should mock be test only?
|
|
"//src/gpu:mock_srcs",
|
|
],
|
|
"//conditions:default": [],
|
|
}) + select_multi(
|
|
{
|
|
"//bazel/common_config_settings:gif_decode_codec": ["//third_party:wuffs"],
|
|
":needs_png": ["//third_party:libpng"],
|
|
"//bazel/common_config_settings:raw_decode_codec": [
|
|
"//third_party:piex",
|
|
"//third_party:dng_sdk",
|
|
],
|
|
":needs_webp": ["//third_party:libwebp"],
|
|
":needs_jpeg": ["//third_party:libjpeg-turbo"],
|
|
},
|
|
default = [],
|
|
) + select({
|
|
":any_freetype_fontmgr": [
|
|
"//third_party:freetype2",
|
|
],
|
|
"//conditions:default": [],
|
|
})
|
|
|
|
cc_library(
|
|
name = "skia_core",
|
|
textual_hdrs = ["//src/sksl:txts"],
|
|
deps = CORE_DEPS,
|
|
)
|
|
|
|
# gazelle:prefix go.skia.org/skia
|
|
gazelle(name = "gazelle")
|