c0c0522e80
Apply -fsanitize-recover=pointer-overflow to third_party code only.
I'm trying to keep Skia behaving the same, avoiding illegal nullptr+k:
- Add null check in SkJSON fast string path.
- Add null check (first alloc) and some comments to SkArenaAlloc.
- March an int index instead dst pointer in SkBase64.
Bug: skia:9731
Change-Id: I646635558ea63ded846b746f2a1f0b4f1e1eacff
Reviewed-on: https://skia-review.googlesource.com/c/skia/+/268109
Reviewed-by: Florin Malita <fmalita@chromium.org>
Reviewed-by: Herb Derby <herb@google.com>
Commit-Queue: Mike Klein <mtklein@google.com>
91 lines
2.1 KiB
Plaintext
91 lines
2.1 KiB
Plaintext
# Copyright 2016 Google Inc.
|
|
#
|
|
# Use of this source code is governed by a BSD-style license that can be
|
|
# found in the LICENSE file.
|
|
|
|
template("third_party") {
|
|
enabled = !defined(invoker.enabled) || invoker.enabled
|
|
config(target_name + "_public") {
|
|
if (enabled) {
|
|
cflags = []
|
|
if (defined(invoker.public_defines)) {
|
|
defines = invoker.public_defines
|
|
}
|
|
if (is_win) {
|
|
include_dirs = invoker.public_include_dirs
|
|
if (is_clang) {
|
|
foreach(dir, invoker.public_include_dirs) {
|
|
cflags += [
|
|
"/imsvc",
|
|
rebase_path(dir),
|
|
]
|
|
}
|
|
}
|
|
} else {
|
|
foreach(dir, invoker.public_include_dirs) {
|
|
if (werror) {
|
|
cflags += [
|
|
"-isystem",
|
|
rebase_path(dir),
|
|
]
|
|
} else {
|
|
cflags += [
|
|
"-I",
|
|
rebase_path(dir),
|
|
]
|
|
}
|
|
}
|
|
}
|
|
} else {
|
|
not_needed(invoker, "*")
|
|
}
|
|
}
|
|
|
|
# You can't make a static_library() without object files to archive,
|
|
# but we can treat targets without object files as a source_set().
|
|
if (defined(invoker.sources)) {
|
|
_mode = "static_library"
|
|
} else {
|
|
_mode = "source_set"
|
|
}
|
|
|
|
target(_mode, target_name) {
|
|
if (enabled) {
|
|
forward_variables_from(invoker, "*", [ "public_include_dirs" ])
|
|
public_configs = [ ":" + target_name + "_public" ]
|
|
|
|
# Warnings are just noise if we're not maintaining the code.
|
|
if (is_win) {
|
|
cflags = [ "/w" ]
|
|
} else {
|
|
cflags = [ "-w" ]
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
set_defaults("third_party") {
|
|
configs = default_configs
|
|
if (!is_official_build) {
|
|
# Official builds don't have warnings to begin with.
|
|
configs -= [ "//gn:warnings" ]
|
|
}
|
|
|
|
if (is_debug) {
|
|
configs += [ "//gn:optimize" ]
|
|
}
|
|
|
|
if (sanitize == "ASAN") {
|
|
configs += [ "//gn:recover_pointer_overflow" ]
|
|
}
|
|
}
|
|
|
|
template("system") {
|
|
config(target_name + "_public") {
|
|
forward_variables_from(invoker, "*", [])
|
|
}
|
|
group(target_name) {
|
|
public_configs = [ ":" + target_name + "_public" ]
|
|
}
|
|
}
|