10d665d000
This extends the pattern in freetype2 to expat, icu, libjpeg-turbo, libpng, libwebp, and zlib, and gives all these an arg to control which to use. Homebrew doesn't have dng_sdk, piex, or sftnly, or I'd have done the same for them too. BUG=skia: GOLD_TRYBOT_URL= https://gold.skia.org/search?issue=4260 DOCS_PREVIEW= https://skia.org/?cl=4260 Change-Id: I82e780502bf2217336e791787f172a6fc8f55460 Reviewed-on: https://skia-review.googlesource.com/4260 Commit-Queue: Mike Klein <mtklein@chromium.org> Reviewed-by: Hal Canary <halcanary@google.com>
38 lines
917 B
Plaintext
38 lines
917 B
Plaintext
# Copyright 2016 Google Inc.
|
|
#
|
|
# Use of this source code is governed by a BSD-style license that can be
|
|
# found in the LICENSE file.
|
|
|
|
template("third_party") {
|
|
config(target_name + "_public") {
|
|
if (defined(invoker.public_defines)) {
|
|
defines = invoker.public_defines
|
|
}
|
|
include_dirs = invoker.public_include_dirs
|
|
}
|
|
source_set(target_name) {
|
|
forward_variables_from(invoker, "*", [ "public_include_dirs" ])
|
|
public_configs = [ ":" + target_name + "_public" ]
|
|
|
|
# Warnings are just noise if we're not maintaining the code.
|
|
if (is_win) {
|
|
cflags = [ "/w" ]
|
|
} else {
|
|
cflags = [ "-w" ]
|
|
}
|
|
}
|
|
}
|
|
|
|
set_defaults("third_party") {
|
|
configs = default_configs - [ "//gn:warnings" ]
|
|
}
|
|
|
|
template("system") {
|
|
config(target_name + "_public") {
|
|
forward_variables_from(invoker, "*", [])
|
|
}
|
|
group(target_name) {
|
|
public_configs = [ ":" + target_name + "_public" ]
|
|
}
|
|
}
|