v8/snapshot_toolchain.gni

# Copyright 2015 the V8 project authors. All rights reserved.
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions are
# met:
#
#     * Redistributions of source code must retain the above copyright
#       notice, this list of conditions and the following disclaimer.
#     * Redistributions in binary form must reproduce the above
#       copyright notice, this list of conditions and the following
#       disclaimer in the documentation and/or other materials provided
#       with the distribution.
#     * Neither the name of Google Inc. nor the names of its
#       contributors may be used to endorse or promote products derived
#       from this software without specific prior written permission.
#
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
# A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
# OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

declare_args() {
  # The snapshot needs to be compiled for the host, but compiled with
  # a toolchain that matches the bit-width of the target.
  v8_snapshot_toolchain = ""
}

# TODO(GYP): For now we only support 32-bit little-endian target builds from an
# x64 Linux host. Eventually we need to support all of the host/target
# configurations v8 runs on.
if (v8_snapshot_toolchain == "") {
  if (host_cpu == "x64" && host_os == "linux") {
    if (target_cpu == "arm" || target_cpu == "mipsel" || target_cpu == "x86") {
      if (target_os == "android" || is_clang) {
        v8_snapshot_toolchain = "//build/toolchain/linux:clang_x86"
      } else if (target_os == "chromeos") {
        # TODO(dpranke): crbug.com/608596: Remove this clause once the
        # CrOS ebuilds are setting v8_snapshot_toolchain directly and
        # we've cleaned up the sysroot settings in //build.
        v8_snapshot_toolchain = "//build/toolchain/linux:clang_x86"
      } else {
        v8_snapshot_toolchain = "//build/toolchain/linux:x86"
      }

    } else if (target_cpu == "x64" || target_cpu == "arm64" ||
               target_cpu == "mips64el") {
      if (target_os == "android" || is_clang) {
        v8_snapshot_toolchain = "//build/toolchain/linux:clang_x64"
      } else if (target_os == "chromeos") {
        # TODO(dpranke): crbug.com/608596: Remove this clause once the
        # CrOS ebuilds are setting v8_snapshot_toolchain directly and
        # we've cleaned up the sysroot settings in //build.
        v8_snapshot_toolchain = "//build/toolchain/linux:clang_x64"
      } else {
        v8_snapshot_toolchain = "//build/toolchain/linux:x64"
      }
    } else {
      assert(false, "Need environment for this arch: $target_cpu")
    }
  } else if (host_os == "mac" && target_os == "win") {
    v8_snapshot_toolchain = "//build/toolchain/mac:clang_$target_cpu"
  } else {
    v8_snapshot_toolchain = default_toolchain
  }
}

# TODO(dpranke): snapshot_toolchain is provided for backwards compatibility
# and should be removed once all callers are updated to refer to
# v8_snapshot_toolchain directly.
snapshot_toolchain = v8_snapshot_toolchain