ae0e92219b
Instead of directly using v8_enable_inspector_override from build_overrides/v8.gni in all the GN configs, set a v8_enable_inspector variable based on v8_enable_inspector_override and use that everywhere. This is the more common pattern seen in over projects, and reduces the need to include //build_overrides/v8.gni in many files. Review-Url: https://codereview.chromium.org/2520683002 Cr-Commit-Position: refs/heads/master@{#41156}
127 lines
3.9 KiB
Plaintext
127 lines
3.9 KiB
Plaintext
# Copyright 2016 the V8 project authors. All rights reserved.
|
|
# Use of this source code is governed by a BSD-style license that can be
|
|
# found in the LICENSE file.
|
|
|
|
import("//build/config/sanitizers/sanitizers.gni")
|
|
import("//build/config/v8_target_cpu.gni")
|
|
import("//build_overrides/v8.gni")
|
|
|
|
declare_args() {
|
|
# Indicate if valgrind was fetched as a custom deps to make it available on
|
|
# swarming.
|
|
v8_has_valgrind = false
|
|
|
|
# Indicate if gcmole was fetched as a hook to make it available on swarming.
|
|
v8_gcmole = false
|
|
|
|
# Turns on compiler optimizations in V8 in Debug build.
|
|
v8_optimized_debug = true
|
|
|
|
# Support for backtrace_symbols on linux.
|
|
v8_enable_backtrace = ""
|
|
|
|
# Enable the snapshot feature, for fast context creation.
|
|
# http://v8project.blogspot.com/2015/09/custom-startup-snapshots.html
|
|
v8_use_snapshot = true
|
|
|
|
# Use external files for startup data blobs:
|
|
# the JS builtins sources and the start snapshot.
|
|
v8_use_external_startup_data = ""
|
|
|
|
# Enable ECMAScript Internationalization API. Enabling this feature will
|
|
# add a dependency on the ICU library.
|
|
v8_enable_i18n_support = true
|
|
|
|
# Enable inspector. See include/v8-inspector.h.
|
|
v8_enable_inspector = v8_enable_inspector_override
|
|
}
|
|
|
|
if (v8_use_external_startup_data == "") {
|
|
# If not specified as a gn arg, use external startup data by default if
|
|
# a snapshot is used and if we're not on ios.
|
|
v8_use_external_startup_data = v8_use_snapshot && !is_ios
|
|
}
|
|
|
|
if (v8_enable_backtrace == "") {
|
|
v8_enable_backtrace = is_debug && !v8_optimized_debug
|
|
}
|
|
|
|
# Points to // in v8 stand-alone or to //v8/ in chromium. We need absolute
|
|
# paths for all configs in templates as they are shared in different
|
|
# subdirectories.
|
|
v8_path_prefix = get_path_info("../", "abspath")
|
|
|
|
v8_inspector_js_protocol = v8_path_prefix + "/src/inspector/js_protocol.json"
|
|
|
|
###############################################################################
|
|
# Templates
|
|
#
|
|
|
|
# Common configs to remove or add in all v8 targets.
|
|
v8_remove_configs = [ "//build/config/compiler:chromium_code" ]
|
|
v8_add_configs = [
|
|
"//build/config/compiler:no_chromium_code",
|
|
v8_path_prefix + ":features",
|
|
v8_path_prefix + ":toolchain",
|
|
]
|
|
|
|
if (is_debug && !v8_optimized_debug) {
|
|
v8_remove_configs += [ "//build/config/compiler:default_optimization" ]
|
|
v8_add_configs += [ "//build/config/compiler:no_optimize" ]
|
|
} else {
|
|
v8_remove_configs += [ "//build/config/compiler:default_optimization" ]
|
|
|
|
# TODO(crbug.com/621335) Rework this so that we don't have the confusion
|
|
# between "optimize_speed" and "optimize_max".
|
|
if (is_posix && !is_android && !using_sanitizer) {
|
|
v8_add_configs += [ "//build/config/compiler:optimize_speed" ]
|
|
} else {
|
|
v8_add_configs += [ "//build/config/compiler:optimize_max" ]
|
|
}
|
|
}
|
|
|
|
if (is_posix && v8_enable_backtrace) {
|
|
v8_remove_configs += [ "//build/config/gcc:symbol_visibility_hidden" ]
|
|
v8_add_configs += [ "//build/config/gcc:symbol_visibility_default" ]
|
|
}
|
|
|
|
# All templates should be kept in sync.
|
|
template("v8_source_set") {
|
|
source_set(target_name) {
|
|
forward_variables_from(invoker, "*", [ "configs" ])
|
|
configs += invoker.configs
|
|
configs -= v8_remove_configs
|
|
configs += v8_add_configs
|
|
}
|
|
}
|
|
|
|
template("v8_executable") {
|
|
executable(target_name) {
|
|
forward_variables_from(invoker,
|
|
"*",
|
|
[
|
|
"configs",
|
|
"remove_configs",
|
|
])
|
|
if (defined(invoker.remove_configs)) {
|
|
configs -= invoker.remove_configs
|
|
}
|
|
configs += invoker.configs
|
|
configs -= v8_remove_configs
|
|
configs += v8_add_configs
|
|
if (is_linux) {
|
|
# For enabling ASLR.
|
|
ldflags = [ "-pie" ]
|
|
}
|
|
}
|
|
}
|
|
|
|
template("v8_component") {
|
|
component(target_name) {
|
|
forward_variables_from(invoker, "*", [ "configs" ])
|
|
configs += invoker.configs
|
|
configs -= v8_remove_configs
|
|
configs += v8_add_configs
|
|
}
|
|
}
|