mirror of
https://sourceware.org/git/glibc.git
synced 2024-12-07 12:10:04 +00:00
1f921a93e4
Continuing fixes for ceil, floor and trunc functions not to raise the "inexact" exception, this patch fixes the versions used on older powerpc32 processors. As was done with the round implementations some time ago, the save of floating-point state is moved after the first floating-point operation on the input to ensure that any "invalid" exception from signaling NaN input is included in the saved state, and then the whole state gets restored rather than just the rounding mode. This has no effect on configurations using the power5+ code, since such processors can do these operations with a single instruction (and those instructions do not set "inexact", so are correct for TS 18661-1 semantics). Tested for powerpc32. [BZ #15479] * sysdeps/powerpc/powerpc32/fpu/s_ceil.S (__ceil): Move save of floating-point state after first floating-point operation on input. Restore full floating-point state instead of just rounding mode. * sysdeps/powerpc/powerpc32/fpu/s_ceilf.S (__ceilf): Likewise. * sysdeps/powerpc/powerpc32/fpu/s_floor.S (__floor): Likewise. * sysdeps/powerpc/powerpc32/fpu/s_floorf.S (__floorf): Likewise. * sysdeps/powerpc/powerpc32/fpu/s_trunc.S (__trunc): Likewise. * sysdeps/powerpc/powerpc32/fpu/s_truncf.S (__truncf): Likewise.
77 lines
2.3 KiB
ArmAsm
77 lines
2.3 KiB
ArmAsm
/* truncf function. PowerPC32 version.
|
|
Copyright (C) 2004-2016 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, see
|
|
<http://www.gnu.org/licenses/>. */
|
|
|
|
#include <sysdep.h>
|
|
|
|
.section .rodata.cst4,"aM",@progbits,4
|
|
.align 2
|
|
.LC0: /* 2**23 */
|
|
.long 0x4b000000
|
|
|
|
/* float [fp1] truncf (float x [fp1])
|
|
IEEE 1003.1 trunc function. IEEE specifies "trunc to the integer
|
|
value, in floating format, nearest to but no larger in magnitude
|
|
then the argument."
|
|
We set "round toward Zero" mode and trunc by adding +-2**23 then
|
|
subtracting +-2**23. */
|
|
|
|
.section ".text"
|
|
ENTRY (__truncf)
|
|
#ifdef SHARED
|
|
mflr r11
|
|
cfi_register(lr,r11)
|
|
SETUP_GOT_ACCESS(r9,got_label)
|
|
addis r9,r9,.LC0-got_label@ha
|
|
lfs fp13,.LC0-got_label@l(r9)
|
|
mtlr r11
|
|
cfi_same_value (lr)
|
|
#else
|
|
lis r9,.LC0@ha
|
|
lfs fp13,.LC0@l(r9)
|
|
#endif
|
|
fabs fp0,fp1
|
|
fsubs fp12,fp13,fp13 /* generate 0.0 */
|
|
fcmpu cr7,fp0,fp13 /* if (fabs(x) > TWO23) */
|
|
mffs fp11 /* Save current FPU rounding mode and
|
|
"inexact" state. */
|
|
fcmpu cr6,fp1,fp12 /* if (x > 0.0) */
|
|
bnllr- cr7
|
|
mtfsfi 7,1 /* Set rounding toward 0 mode. */
|
|
ble- cr6,.L4
|
|
fadds fp1,fp1,fp13 /* x+= TWO23; */
|
|
fsubs fp1,fp1,fp13 /* x-= TWO23; */
|
|
fabs fp1,fp1 /* if (x == 0.0) */
|
|
/* x = 0.0; */
|
|
mtfsf 0xff,fp11 /* Restore previous rounding mode and
|
|
"inexact" state. */
|
|
blr
|
|
.L4:
|
|
bge- cr6,.L9 /* if (x < 0.0) */
|
|
fsubs fp1,fp1,fp13 /* x-= TWO23; */
|
|
fadds fp1,fp1,fp13 /* x+= TWO23; */
|
|
fnabs fp1,fp1 /* if (x == 0.0) */
|
|
/* x = -0.0; */
|
|
.L9:
|
|
mtfsf 0xff,fp11 /* Restore previous rounding mode and
|
|
"inexact" state. */
|
|
blr
|
|
END (__truncf)
|
|
|
|
weak_alias (__truncf, truncf)
|
|
|